Header3
PageHeader
Body
Body Large (20/130%/14)
Body Large (20/130%/14) #2

A Collection of Fiddle Tunes of New England & Related Traditions

Fiddle Tunes in abc Notation: Reels, Part 2 (G–O)

Here is the second page of Reels from Lamprey River Band Tunebook and other sources. See the first page for some discussion of reels.

Some of the tunes included here are probably really polkas, marches and hornpipes. I include them here because they are likely to be played as if they were reels, and used as reels would be used for dancing.

Notes:

  • Each section is presented in alphabetical order. Tunes  from the Lamprey River Band Tunebook are marked as such.
  • All tunes are in abc format, which allows music to be written in text form.
    • With free software it can be displayed as standard notation or it can be played back to you.

Useful Links:

  • How to display tunes as standard notation and play them back on your computer: go to this page.
  • To produce musical notation that looks like the PDFs on this web site, please go to this page and follow instructions given there.
  • The tunes are available on this page as downloadable abc and PDF documents.
  • A searchable listing of tunes on the web site is here. You can sort them by any column.
  • A listing of the sources I used in preparing this web site is here.
  • There is a chord book available to download in PDF format for all tunes on this web site.

 

X:7049

T:Gaspé Reel

N:The A part especially is based on the playing of Louis Beaudoin. A few notes

N:are in parentheses. They may be played as usual, as ghost notes, or treated as rests.

M:C|

L:1/8

R:Reel

G:Reels ~ Canadian ~ Quebec ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:D

   "D"  f3e/f/  e2d2 | "D"  "<("">)"AAFA B2A2 |\

   "A7" g3f/g/ f2e2 | "A7" BABc B2A2 |

   "D"  f3e/f/  e2d2  | "D"  "<("">)"AAFA B2A2 |\

   "A7" g2>g2 f2A2 |\

   "A7" B2c2 "D" d4 :|

|: "A7" e2f2 g2fe | "D"  f2g2 a4 |\

   "A7" e2f2 gfe2 | "E7" BABc "A7" ((3BcB) A2 |

   "A7" e2f2 g2fe | "D"  f2g2 a4 |\

   "A7" b2a2 gfe2 | "A7" B2c2 "D" d4 :|

%%vskip 25

 

X:7369

T:Glise de Sherbrooke

T:La Grande Chaine, Reel de Tadoussac, Glise de Sherbrooke, Quadrille de chez nous

S:As played by Ralph Page's New Hampshire Orchestra (as Glise a Sherbrooke),

S:Michael Herman, Folk Dancer Records MH 1073-B.

N:The Identitairs Québécois web site <http://www.mustrad.udenap.org> comments that

N:the tune is an adaptation of Home Sweet Home, thus the name Quadrille de chez nous.

N:The Ralph Page Orchestra started each phrase of the B part on a G chord.

N:For many years that chord has been played as a C chord or, with some versions

N:of the melody, as | G-C | G |

M:2/4

L:1/16

R:Reel

G:Reels ~ Canadian ~ Quebec ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:G

%%textfont Palatino-Italic 14

%%text As Played by the Ralph Page Orchestra

%%textfont Palatino-Roman 16

%%

   ((3DEF)|\

"G" G2G2 BABc | "G" d2dc B2GB | "D7" c2cB A2FA | "G" d2dc B2DE |

"G" G2G2 BABc | "G" d2dc B2GB | "D7" c2cB ABAF | "G" G2B2 G2  :|

|:((3def) |\

"G;C" g2g2 efge | "G" d2dc B2AB | "D7" c2cB A2FA | "G" d2dc B2z2 |

"G;C" g2g2 efge | "G" d2dc B2AB | "D7" c2cB ABAF | "G" G2B2 G2  :|

%%vskip 25

 

X:7370

%%scale .7

T:Glise de Sherbrooke

T:Reel de Tadoussac

T:La Grande Chaine, Quadrille de chez nous

S:Melody and chords as recorded by Joseph Allard, 1945.

N:See Glise de Sherbrooke #1 for further notes.

M:2/4

L:1/16

R:Reel

G:Reels ~ Canadian ~ Quebec ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:G

%%textfont Palatino-Italic 14

%%text As Played by Joseph Allard

%%textfont Palatino-Roman 16

%%

  GA |\

"G" B2B2 "C" cBce | "G" d2dc BGBd | "D7" cBcA FDFA | "G" Addc "D7"  BGDG |

"G" B2B2 "C" cBce | "G" d2dc BGBd | "D7" cBcA FDFA | "G" G2"D7"G2 "G" G2  :|

|:Bd |\

"C" gagf ecge | "G" d2dc BGBd | "D7" cBcA FDFA | "G" Addc "G7" BGBd|

"C" gagf ecge | "G" d2dc BGBd | "D7" cBcA FDFA | "G" G2"D7"G2 "G" G2  :|

 

X:7371

T:Glise de Sherbrooke

T:La Grande Chaine

T:Le Tadoussac, Quadrille de chez nous

N:This is based on Louis Beaudoin's playin of the tune, under the name

N:La Grande Chaine. This most likely referred to the name of a dance or

N:dance figure done to the tune. More information with Glise de Sherbrooke #1.

M:2/4

L:1/16

R:Reel

G:Reels ~ Canadian ~ Quebec ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:G

%%textfont Palatino-Italic 14

%%text As Played by Louis Beaudoin

%%textfont Palatino-Roman 16

%%

DGA |\

"G" B2Bc BAGB | "G" d2d2 BGGB | "D7" cdcB AEAd | "G" dedc BGGA  |

"G" B2Bc BAGB | "G" d2d2 BGGB | "D7" cdcB AGFA | "G" G2GG G   :|

|:def|\

"G" gagf "C" efge | "G" d2d2 BGGB | "D7" cdcB AEAd | "G" dedc BGAB |

"G" gagf "C" efge | "G" d2d2 BGGB | "D7" cdcB AGFA | "G" G2GG G   :|

 

X:7555

T:La Grondeuse

T:The Silver Spire

S:Canterbury Country Dance Orchestra, Mistwold (F&W Records, F&W 5, 1974)

N:Melody and chords are from the Canterbury Orchestra recording. The alternate

N:chords in the B part reflect the fact that Bob McQuillen had a few different

N:ways of playing it, and I added in the F#7 that I sometimes play.

M:2/4

L:1/16

R:Reel

G:Reels ~ Canadian ~ Quebec ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:D

  "D" D2FE       D2FA | "D" dcde     fdAF | "G" G2BG "D" F2AF | "A7" EFGE      DCB,A, |

   "D" D2FE       D2FA | "D" dcde     fdAF | "G" G2BG "D" F2AF | "A7" ECA,C "D" D4    :|

|: "A" A,B,CD     EFGF | "A" EDEF     GABc | "D" dcdB     ABcd | "D"  fagf  "A" e2A2   |

   "D" d2fd "F#7 or A7;G" c2ec | "G" BcdB "D/F#" AFDF | "A7/E;G" G2BG "D;A7" F2AF | "A7" ECA,C "D" D4    :|

 

X:7559

T:Growling Old Man and the Cackling Old Woman

T:Growling Old Man and the Grumbling Old Woman

N:This is a standard New England version, although the B-part chords are a bit

N:unusual. Simon St. Pierre, Maine French fiddler, played an interesting rather

N:different version. Go to http://www.mainefiddlecamp.org/music-of-simon-st-pierre/

N:and click on The Woods of Maine for a PDF, or on the abc version right below.

M:2/4

L:1/16

R:Reel

G:Reels ~ Canadian ~ Quebec ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:Am

   A,B, |\

"Am" CA,[A,E]A, CA,[A,E]A, | "G" B,G,[G,D]G, B,G,[G,D]G, |\

"Am" CA,[A,E]A, CA,[A,E]A, | "G" G,A,B,G,  "Am" [A,2E2] A,B, |

"Am" CA,[A,E]A, CA,[A,E]A, | "G" B,G,[G,D]G, B,G,[G,D]G, |\

"Am" CA,[A,E]A, CA,[A,E]A, | "G" G,A,B,G,  "Am" [A,2E2] :|

|:^cd |\

"A"  e^fed ^cdef | "C"  ((3gfe) dc "G" BGG2  |\

"A"  e^fed ^cAcd | "Em" ea-a^g a2e^f    |

"A"  g^fed ^cdef | "C"  ((3gfe) dc "G" BGGB  |\

"Am" cABG "G" AGED | "Em" GEDB, "Am" A,2 :|

%%vskip 20

 

X:8463

%%pagescale .95

T:L'homme à deux femmes

S:Jean-Marie Verret, from Jean-Marie et Martin Verret, Quadrille du

S:XIXe et XXe siècle. 1997

N:The title probably refers to an associated dance rather than the tune.

N:Chords are probably mostly correct. The parts involving diminshed chords seem to

N:work best in root position.

M:2/4

L:1/16

R:Reel

G:Reels ~ Canadian ~ Quebec ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:G

  Bc |\

"G" (Bd-d)d dBGB  | "G" (Bd-d)d dBGB    | "G" d2gg "Gdim" g2g2    | "D7" f4 ((3fgf) AB |

"D7" (Bc-c)c cBAB | "D7" (Bc-c)c cBAB   | "D7" c2ee "Daug" e2e2   | "G" d3c B2c2 |

"G" (Bd-d)d dBGB  | "G" (Bd-d)d dBGB    | "G" d2gg "Gdim" g2g2    | "D7" f2>e2 e2>c2 |

"D7" c2AB cdef    | "G" ((3ege) dd d2ed |  "A7" ^c2e2 abaf |1 "D7" d4d2 :|2 "D7" d2>d2 ||

|:efed |\

"D7" c2f2 c2f2 | "D7" c2f2 fgfe  | "G" d2g2 d2gd | "G" B4 ABAG   |

"D7" F2G2 A2B2 | "D7" c3d efed   | "G" d4-dedc   | "G" B2g2 efed |

"D7" c2f2 c2f2 | "D7" c2f2 fgfe  | "G" d2g2 d2gd | "G" B4 ABAG   |

"D7" F2GA Bcde | "D7" f2d2 f2>e2 | "Am" ddBd  "D7" e2f2 |1 "G" g3g :|2 "G" g3 ||

|:D E2F2 |\

"G" G3B G2B2 | "G" GBGD E2F2 | "G" G2>B2 "Gdim" G2B2 | "D7" A2>F2 DEFG |

"D7"A2AA "D7" A2"Ddim"B2     | "D7" A2DD "Ddim" DEFG | "D7" A2AA A2B2  |1 "G" G3 :|2  "G" G6 |]

 

X:9424

T:Indian Reel

M:C|

L:1/8

R:Reel

G:Reels ~ Canadian ~ Quebec ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:G

   Bc |\

"G"  d2gd B2dB |  "G" G2BG D2B2 |\

"D7" AGAB c2A2 |  "G" GABc d2Bc |

"G"  d2gd B2dB |  "G" G2BG D2B2 |\

"D7" AGAB c2FA |1 "G" G2[G2B2]G2 :|2 "G" G2[G2B2]G2z2 ||

K:C

|: "C" c2Gc e2ce | "C" g2gg  g2f2 |\

   "C" edeg "G7" fedc | "G7" BGAB "C" cBAB |

   "C" c2Gc e2ce | "C" g6    f2   |\

   "C" edeg "G7" fedc |1 "G7" BGAB "C" c2G2 :|2 "G7" BGAB "C" c2 |]

%%vskip 20

 

X:10475

T:Joys of Québec

T:Les joyeuses québécoises ~ Two-Part Version

C:Fortunat Malouin

N:This is a fairly standard two-part version of the tune. I've also included a

N:three-part version.

M:2/4

L:1/16

R:Reel

G:Reels ~ Canadian ~ Quebec ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:A

%%textfont Palatino-Italic 14

%%text Two-Part Version

%%textfont Palatino-Roman 16

%%

 ee |\

   "A"  eccc c2ee     | "A"  eccc  c2ee     | "A" f2e2 d2c2 | "E7" dBBB B2dd |

   "E7" dBBB  B2dd    | "E7" dBBB B2ef      |1 "E7" g2((3fgf) e2d2 \

|  "A" c4 c2 :|2 "E7" g2e2 f2g2 | "A" a6 (A/B/c/d/) ||

|: "A" e4 "D" f4      | "A" e3f e2AB        |\

 "A" c2c2 "D" d2d2    | "A" c2>d2 c2AB      |

"E7" c2A2     G2A2    | "E7" B4-B2ef        |1 "E7" g2((3fgf) e2d2 |\

"A" c4 c2 (A/B/c/d/) :|2 "E7" g2e2 f2g2  | "A" a4 a2       |]

%%vskip 15

%%textfont Palatino-Bold 16

%%text

%

%%textfont Palatino-Bold 16

%%text Melodic Variation (A Part Meas. 3-4)

 "A" fAeA dAcA | "E7" dBBB B2dd |\

%%vskip 20

 

X:10477

T:Joys of Québec

T:Les joyeuses québécoises ~ Three-Part Version

C:Fortunat Malouin

N:Here is a three-part version; a two-part version is included as well.

N:The C part is as played by Marcel Robidas of Dover, NH at the Barn, Winter 1996.

N:I've shown two ways he transitioned from the B part. One adds an extra beat and the

N:other adds a full measure. Marcel would play the third part unpredictably every 2-4 times.

N:The extra beats would signal that a C part was next. Otherwise the ending of the B part

N:would be played as in the two-part version.

M:2/4

L:1/16

R:Reel

G:Reels ~ Canadian ~ Quebec ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:A

%%textfont Palatino-Italic 14

%%text Three-Part Version

%%textfont Palatino-Roman 16

%%

 ee |\

   "A"  eccc c2ee     | "A"  eccc  c2ee     | "A" f2e2 d2c2 | "E7" dBBB B2dd |

   "E7" dBBB  B2dd    | "E7" dBBB B2ef      |1 "E7" g2((3fgf) e2d2 \

|  "A" c4 c2 :|2 "E7" g2e2 f2g2 | "A" a6 (A/B/c/d/) ||

|: "A" e4 "D" f4      | "A" e3f e2AB        |\

 "A" c2c2 "D" d2d2    | "A" c2>d2 c2AB      |1

"E7" c2A2     G2A2    | "E7" B4-B2ef        | "E7" g2((3fgf) e2d2 |\

"A" c4 c2 (A/B/c/d/) :|2

"E7" c2A2     G2A2    | "E7" B4 g2f2 | "E7" e2e2 f2g2  | [M:3/4]"A" afec A2A2 B2c2 ||

[M:2/4] "E7" d4>B4 | "E7" G4 f4 | "A" .e2z2 {f}e2d2 | "A" c2A2 B2c2 |\

"E7" d4 B4 | "E7" G4 F4 | "A" E2>F2 E2D2 | "A" E2A2 c2d2 |

"A" e4 "D" f4      | "A" e2z2 z2 AA        | "A" c4 "D" c2<sd2    | "A" c4 .ez zc      |\

"A" c2A2     G2A2    | "E7" B4-B2ee | "E7" f2e2 f2g2 | "A" aece A2 |]

%

%%vskip 15

%%textfont Palatino-Bold 16

%%text Melodic Variation (A Part Meas. 3-4)             Alternative Transition to C Part

 "A" fAeA dAcA | "E7" dBBB B2dd |\

%%staffbreak 1.5cm

 "_B-part ending" "E7" e2e2 f2g2 |  "A" a2aa a2a2 | "A" a2A2 B2c2 ||\

 "_C Part""E7" d4>B4 | "E7" G4 f4 |

%%vskip 20

 

X:10634

T:Judy's Reel

T:Maid Behind the Bar

N:This tune has been known as Judy's Reel in New England; in Irish music

N:circles it's more likely called the Maid Behind the Bar.

M:4/4

L:1/8

R:Reel

G:Reels ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:D

   "D"  FAAB AFED | "D"  FAAB "(F#/A#)" ABde |\

   "Bm" fBBA Bcde | "Bm" fBBA "A7"      BcdA |

   "D"  FAAB AFED | "D"  FAAB "(F#/A#)" ABde |\

   "Bm" fBBA BcdB | "A7" AFEF "D"  D4  :|

|: "D"  fgab afde | "D"  fdad      bdad |\

   "Em" efga bgef | "Em" ((3gfe) be "A7" geeg |

   "D"  fgaf bfaf | "D"  defd      efde |\

   "Bm" fBBA BcdB | "A7" AFEF "D"  D4  :|

%%vskip 20

 

X:11282

T:Kildare's Fancy

S:Rod & Randy Miller, $2New England Chestnuts Vol. 1$0. Alcazar Records FR 203,

S:1980 (melody & chords)

M:4/4

L:1/8

R:Reel

G:Reels ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:D

  dB |\

"D" AFDF A2dB | "D" AFAd fedc | "G" BGBd "Em" gfed | "A7" cdcB     A2dB |

"D" AFDF "F#m/C#" A2dB | "D" AFAd fedc | "G" BGBd "Em" gfed | "A7" ceAc "D" d2  :|

|:de |\

"D" fdcd BdAF | "D" DFAd f2ef | "Em" eAfA gagf | "A7" edcB     A2de |

"D" fdcd BdAF | "D" DFAd f2ef | "G" eAfA "Em" gfed | "A7" cABc "D" d2  :|

%%vskip 20                                                               20

 

X:11290

T:Kitchen Girl

N:The variation with the E-major chord comes from a recording of the tune

N:by Spaelimenninir from their record Burturav.

M:C|

L:1/8

R:Reel

G:Reels ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:Amix

   "A" a4 "G" g4 | "A"  efed   c2cd  |\

   "A" e2ef gaba | "Em" g2e2   e2c2  |

   "A" a4 "G" g4 | "A"  efed   c2cd  |\

   "A" e2ef "Em" gfed | "A" c2A2 A4 :|

K:Am

|: "Am" ABcA "G" BAGB  |  "Am" ABAG "Em" E2EG |\

   "Am" A2B2     c2d2 |  "Em" e2ef      edcB |

   "Am" ABcA "G" BAGB |  "Am" ABAG "Em" E2EG |\

   "Am" cBAc "G" BAGB | "Am" A4 A4 :|

%%vskip 20

%%annotationfont Palatino-Bold 16

"^A-Part Variation (meas. 3-4)""A" e2ef gaba | "E" ^g2e2   e2c2  |\

%%staffbreak 2cm

 "^B2 Altertnate Final Measure""A" A2^cd e^f ((3gfe) |]

 

X:12172

T:Leventine's Barrel

S:Laurie Andres, $2Fantastic Hornpipe$0. Rooster Records, RSTR 122, 1983.

S:Philippe Bruneau, $2Danses pour veillés Canadiennes.$0 Philo, FI-2006, 1975.

N:Based on the playing of Laurie Andres. The alternate measures A4 and B4 are common

N:ways of playing the tune.The alternate measures B1-2 and B5-6 are as Philippe Bruneau

N:played the tune. The tune is often played in G, but the melody is slightly

N:different. It's presented next.

M:2/4

L:1/16

R:Reel

G:Reels

H:This tune is from the NH Country Dance website. Look for more tunes

H:(New England, Canadian, Swedish) as well as resources for abc notation and

H:New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:D

%%textfont Palatino-Italic 14

%%text In D

%%textfont Palatino-Roman 16

%%

fe|\

"D" dfAd f2fe     | "D" d2ba ^gafd | "A7" ceAc eAce | "^\*1*" "A7" dfba ^gafe |

"D" dfAd f2fe     | "D" d2ba ^gafd | "A7" ceAc eAce |1 "D" d2f2 d2  :|2 "D" d2f2 "D7" d2z2 ||

|: "^*3*" "G" B2c2 d2b2- | "D" ba^ga f2ed | "A7" ceAc eAce | "^*2*" "D" defg "D7" afed   |

"^*3*" "G" B2c2 d2b2-    | "D" ba^ga f2ed | "A7" ceAc eAce |1 "D" d2f2 "D7" d2z2  :|2 "D" d2f2 d2 |]

%%vskip 15

%%textfont Palatino-Bold 16

%%annotationfont Palatino-BoldItalic 14

%%text Here are some variations in the melody.

%%vskip 10

||"^*1*" "_Alt. Meas. A4" defg a2fe ||\

%%staffbreak 1.5cm

||"^*2*" "_Alt. Meas. B4" defg a2 zA ||\

%%staffbreak 1.5cm

|| "^*3*" "_Alt. B meas. 1-2, 5-6" B2c2 d2>b2 | ba^ga f2ed ||

%%vskip 15

 

X:12174

T:Leventine's Barrel

N:This is how it's often played in G. The biggest difference is in the first

N:two measures of the B part.

M:2/4

L:1/16

R:Reel

G:Reels

H:This tune is from the NH Country Dance website. Look for more tunes

H:(New England, Canadian, Swedish) as well as resources for abc notation and

H:New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:G

%%textfont Palatino-Italic 14

%%text In G

%%textfont Palatino-Roman 16

%%

BA|\

"G" GBDG B2BA | "G" G2ed ^cdBG | "D7" FADF ADFA | "D7" GABc d2BA |

"G" GBDG B2BA | "G" G2ed ^cdBG | "D7" FADF ADFA |1 "G" G2B2 G2 :|2 "G" G2B2 "G7" G3 ||

|:d|\

"C" e2f2 g2fe | "G" ed^cd B2AG | "D7" FADF ADFA | "G" GABc "G7" d2d2 |

"C" e2f2 g2fe | "G" ed^cd B2AG | "D7" FADF ADFA |1 "G" G2B2 "G7" G3 :|2 "G" G2B2 G2 |]

 

X:12272

T:Liberty

M:4/4

L:1/8

R:Reel

G:Reels ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:D

  de\

| "D" f2A2 f2A2 | "D" fefg f2ef | "G" g2B2     g2B2 | "G" gfga g2fe |

  "D" f2A2 f2A2 | "D" fefg f2ef | "G" gfed "A7" cABc | "D" d2f2 d2  :|

|:FG\

| "D" A2AB AGFE | "D" DFAd f2d2 | "D" A2AB     AGF2 | "A7" E2EE E2FG |

  "D" A2AB AGFE | "D" DFAd f2d2 | "G" gfed "A7" cABc | "D" d2f2 d2  :|

 

X:12290

T:Little Judique Reel

M:2/4

L:1/16

R:Reel

G:Reels ~ Canadian ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:D

f3g |\

"D"  a^gab a2f2    | "D"  d2A2 A2fg | "D"  a^gab a2f2 | "D"  d6 ef  |

"A7" gfga  g2e2    | "A7" c2A2 A2ef | "A7" gfga  g2e2 | "A7" c6 fg  |

"D"  a^gab a2f2    | "D"  d2A2 A2fg | "D"  a^gab a2f2 | "D"  d4 g3a |

"G"  b2gb "D" a2fa | "A7" g2eg "D" f2ed |\

"A7" c2Ac     a2c2 | "D"  d4 ||

|:c2d2 |\

"A"  .e4  e3f  | "A" e2c2 B2A2 | "D" a^gab a2f2       | "A" e6 f^g |

"D"  a3b  a2f2 | "A" e2c2 a3f  |1 "B7""(A)" e2c2 B2A2 | "E7" B4   :|2\

"B7""(E7)" e2c2 "E7" B2c2 | "A" A4 |]

 

X:12457

T:Logger's Breakdown

M:4/4

L:1/8

N:A great Canadian Bb reel.

R:Reel

G:Reels ~ Canadian

H:This tune is from the NH Country Dance website. Look for more tunes

H:(New England, Canadian, Swedish) as well as resources for abc notation and

H:New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:Bb

   "Bb" B,2DF BFDF | "Eb" E2GB eBGB   | "F7" F2Ac fcAc   |"Bb" BdcA BGFD |

   "Bb" B,2DF BFDF | "Eb" E2GB eBGB   | "F7" F2Ac fcAc   |"Bb" BdcA B4  :|

|: "Bb" B2df b2fb  | "Eb" a2g2 g^f g2 | "F7" A2 cf a2 fa | "Bb" g2f2f=ef2|

   "Bb" B2df b2fb  | "Eb" a2g2 g^f g2 | "F7" f2 fg afcA  | "Bb"BdcA B4  :|

 

X:12471

T:Louis Cyr

M:2/4

L:1/16

C:Jean-Claude Mirandette

S:Jean-Marie Verret and Guy Bouchard as played at Ashokan in 1997.

N:About the endings. The A-part endings are how I learned the tune. Jean-Marie

N:played them more as in the alternate A-part endings. The B-part endings are

N:how I learned them and also how Jean-Marie played them. I believe these B-part

N:endings are different from how it was written. The alternate B-part

N:endings, from Pascal Gemme, should be closer.

R:Reel

G:Reels ~ Canadian ~ Quebec

H:This tune is from the NH Country Dance website. Look for more tunes

H:(New England, Canadian, Swedish) as well as resources for abc notation and

H:New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:G

   "G" G,2G,B, D2B,D | "C" EDEF "G" G2GA | "G" BAGB AGED                                                                                          | "C" EDEF "D7" (3(EFE) DB, |

"G" G,2G,B, D2B,D    | "C" EDEF "G" G2GA | "G" BAGB "C" AGED     |1 "D7" EGFA "G" G2DB, :|2 "D7" EGFA "G" G2GA ||

|: "G" BAGB A2GA     | "G" BAGB A2AB     | "C/C" cBAc "G/B" B2AB | "Am" cABG "D7" A2GA |

"G" BAGB A2GA        | "G" BAGB AGED     | "Em" E z [eB][eB] [eB] z [FA,][FA,] |1\

   "D7" [FA,]z [EB,][EB,] "Em" [EB,] z GA:|2 "D7" [FA,]z [EB,][EB,] "Em" [EB,] z E z |]

%%stretchstaff 0

%%textfont Palatino-Italic 16

%%text Final Ending

 "D7" [FA,]z [EB,][EB,] "Em" E4 | "Em" E4 x4 |]

%%vskip 10

%%text The following are alternate endings to the A and B parts of the tune.

%%vskip 10

"@0,-25Alternate A-Part Endings"\

|1 EDEF GEDB, y25 |:2 EDEF G2GA |]

%%vskip 15

"_Alternate B-Part Endings"\

|1 E2(3EEE E2(3FFF | FDE2 E2GA :|2 E2(3EEE E2(3FFF | FDE2 E2DB, |

%%vskip 20

 

X:13033

T:Mackilmoyle Reel

N:Jos Bouchard recorded a somewhat twisted, although 32-bar, version of the tune

N:in 1938. About 5 years later Don Messer recorded a version very much like this one.

N:The phrasing was straightened out. The Jos Bouchard version treated the four opening

N:notes as the beginning of the phrase. Don Messer's version treated them as

N:lead-in notes. There's another version played in New England which is melodically much

N:like the Don Messer's version but which begins the phrase as Jos Bouchard did.

M:2/4

L:1/16

R:Reel

G:Reels ~ LRB

H:From the Lamprey River Band Tunebook. Look for more tunes plus resources for

H:abc notation and New England traditional music and dance; URL below.

U: s = !slide!       % To preserve font, staff layout & other formatting,

U: t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ  % accompanying instructions for how to use it.

F: Tunes - nhcountrydance.com/the-tunes.html

F: File Header & instructions - nhcountrydance.com/headers.html

K:D

   DFAd |\

"D" fdfd "A7" cdec | "D" dBAF "D7" DFA=c | "G" BGBG "D" FGAF  | "A7" EA,A,E DFAd |

"D" fdfd "A7" cdec | "D" dBAF "D7" DFA=c | "G" BGBd "A7" cdec | "D" d2[f2d2] :|

|: cdef |\

"A7" gfg2 Ace^g | "D" a^ga2 e^def | "A7" =gfge "E7" dfed | "A7" cBAA Acef |

"A7" gfg2 Ace^g | "D" a^ga2 e^def | "A7" =gfge      cdec | "D" d2[d2f2] :|

 

X:13049

T:Mason's Apron

N:The Bm is an alternate chord.

M:2/4

L:1/16

R:Reel

G:Reels ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:A

g2 |\

"A" a2A2 ABAF | "A" EFAB c2BA | "E" d2B2     BcBA | "E" dcde    fefg |

"A" a2A2 ABAF | "A" EFAB c2c2 | "D" dcde "A" fefg | "E" a2A2 "A" A2 :|

|:ed |\

"A" cAeA fAeA | "A" cAce fedc | "Bm;E" dBfB gBfB | "E" dBdf    gfed |

"A" cAeA fAeA | "A" cAce fedc | "D"  dcde "A" fefg | "E" a2A2 "A" A2 :|

%%vskip 25

 

X:13168

T:Merry Blacksmith

T:Paddy on the Railroad

M:C|

L:1/8

R:Reel

G:Reels ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:D

A2 |\

"D" d2dA BAFA | "D" ABdA BAFA      | "D" ABde "Bm" f2ed | "Em" Beed "A7" egfe |

"D" d2dA BAFA | "D" ABdA "D7" BAFA | "G" ABde "D" fdec  | "A7" dBAF "D" D2   :|

|:fg |\

"D" a2ag fgfe  | "D" d2dA BAFA      | "D" ABde "Bm" f2ed | "Em" Beed "A7" egfe |

"D" abag  fgfe | "D" d2dA "D7" BAFA | "G" ABde "D" fdec  | "A7" dBAF "D" D2   :|

%%vskip 25

 

X:13274

%%scale .70

T:Midsummer Moon

C:Melody & chords by Sarah Hydern, flute player for the Lamprey River Band

M:4/4

L:1/8

R:Reel

G:Reels ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:Bm

                                       "Bm" B2dB "A" cBAc | "Bm"  BFdF "F#m" eFcF |\

   "Bm" B2dB "A" cBAc | "F#m" FEFA Bcdc  |

   "Bm" B2dB "A" cBAc | "Bm"  BFdF "F#m" eFcF |\

   "Bm" BABc "A" dcde | "F#m" fgfe dcBc :|

|: "D"  d2fd "G" gdfd | "A"   ecAc d2c2  |\

   "D"  d2fd "G" gdfd | "A"   ecAc dedc  |

   "D"  d2fd "G" gdfd | "A"   ecAc d2c2  |\

   "Bm" BABc "A" dcde | "F#m" fgfe dcBA :|

 

X:13289

%%scale .70

T:Miss Brown's Reel

S:From the repertoire of John Taggart, "Recollection of a Busy Life, the memoir of John

S:Adams Taggart (1854-1943)". This version is based on transcriptions from the book

S:reproduced by Randy as well as the New Hampshire Fiddlers Union, "The Music of John

S:Taggart (1854-1943)", Front Hall Records FHR-204C, 1989.

N:Much thanks to Randy Miller who found this book in the collection of the New Hampshire

N:Historical Society Library. The repertoire and sometimes interesting versions of tunes

N:likely represent the dance repertoire of the region a century or more ago.

M:C|

L:1/8

R:Reel

G:Reels ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:D

   "D"  D2D2     DFAF  |  "D" dFAF dFAF  |\

   "Em" E2E2     EFGA  |  "A" edcB AGFE  |

   "D"  D2D2     DFAF  |  "D" dFAF GFED  |\

   "Em"  EFGg "A" fgec |1 "D" d2d2  d4  :|2 "D" d2d2 d2ag ||

|: "D"  fdfa     fdfa  |  "D" fdfa  b2ge |\

   "Em"  ceAe     ceAe |  "A" cdef  g2ag |

   "D"  fdfa     fdfa  |  "D" fdfa  b2gf |\

   "Em"y  gbag "A" fedc |1 "A" dfec "D"  d2ag :|2 "A" dfec "D" d4 |]

%%vskip 25

 

X:13289

T:Miss Mason's Hornpipe

C:Bob McQuillen

N:Written by Bob McQuillen for Sarah Mason, caller and whistle in the Lamprey River Band.

M:C

L:1/8

R:Reel

G:Reels ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:A

AF |\

"A" EcBA "D"  F2AB | "A" cecA "E7"  BAcB  |\

"A" A2AF      EFAc | "C#m" e2c2 c2ce |

"D" fefg      a2af | "A" eaec "E7"  B2cB  |\

"A" AFEF "E7" Aced | "A" c2A2       A2   :|

|:ef |\

"A" a2af      ecef | "A"   afec     e2ce |\

"D" feaf "E7"  ecBc | "F#m" A2F2     F2ef |

"A" a2af      ecBc | "A"   ABce "D" f2af |\

"A" ecAc "E7" BcAF | "A"   E2A2     A2  :|

 

X:13464

T:Reel de Montreal

M:C|

L:1/8

R:Reel

G:Reels ~ Canadian ~ Quebec ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:G

  "G" {Bd}g2fe dcBA |  "G" GBDG B2AG  |\

  "D7" FADF    AcBA |  "G" GBDG B2z2  |

  "G" {Bd}g2fe dcBA |  "G" GBDG B2AG  |\

  "D7" FGAB    cdef |1 "G" g2gg g2z2 :|2 "G" g2gg g2 ||

K:D

|:AB |\

   "D"  A2FA  d2Ad |  "D" f2df a2ab |\

   "A7" ag-g2 e2g2 |  "D" b2a2 fedB |

   "D"  A2FA  d2Ad |  "D" f2df a2ab |\

   "A7" ag-g2 e2c2 |1 "D" defe d2  :|2 "D" defe d2z2 |]

 

X:13468

T:Morpeth Rant

M:4/4

L:1/8

R:Reel

G:Reels ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:D

A2 |\

"D" d2AG FDFA | "G" BGBd "A7" cAce | "D" f2fd "G" gfed | "A7" c2e2 e2Ac     |

"D" d2AG FDFA | "G" BGBd "A7" cAce | "D" f2fd "A7" gfec | "A7" A2d2 "D" d2 :|

|: A2  |\

"D" dfaf dfaf | "G" gfef g2ef | "A7" gfed cdeg | "D" fefg f2f2 |

"D" dfaf dfaf | "G" gfef g2ef | "A7" gfed caag | "D" f2 d2d2  :|

 

X:13470

T:Mother's Reel

N:When playing for a dance it generalliy makes sense to end at the end of the dance.

N:Otherwise it would resolve better to end on the A part or possibly the B part.

M:C|

L:1/8

R:Reel

G:Reels ~ Canadian ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:C

  "C"  e3d  cBcA  |  "C"  GAGF EGFE   | "G7" DGBG dGBG   |  "G7" DGBd gagf         |

   "C"  efed cBcA |  "C"  GAGF EGFE   | "G7" DGBG dGAB   |1 "G7"  cedB "C" c2z2   :|2 "G7" cedB "C" c2 ||

K:G

|:Bc |\

"G"  d2d^c defg   |  "G"  d2d^c defg  | "Em" B3c   BAGA  |  "Em" BcBA "D7;Em" B2Bc |

"G"  d2d^c defg   |  "G"  d2d^c defg  | "D7" abag  fdef  |1 "D7"  gagf  "G" g2    :|2 "D7" gagf "G" g2z2 ||

K:C

|: "C" c2ec gcea  | "C" ggec "G" BcdG | "C" c2ec gcea    | "C" ggec "G" Bcd2      :|

%%vskip 20

 

X:14173

T:New Century Hornpipe

S:From the repertoire of John Taggart, "Recollection of a Busy Life, the memoir of John

S:Adams Taggart (1854-1943)". This version is based on transcriptions from the book

S:reproduced by Randy as well as the New Hampshire Fiddlers Union, "The Music of John

S:Taggart (1854-1943)", Front Hall Records FHR-204C, 1989.

N:Much thanks to Randy Miller who found this book in the collection of the New Hampshire

N:Historical Society Library. The repertoire and sometimes interesting versions of tunes

N:likely represent the dance repertoire of the region a century or more ago.

L:1/8

R:Reel

G:Reels ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:D

  AG |\

"D" F2D2      D2EF | "A7" G2E2      E2AG |\

"D" FDFG      ABAG | "D"  FGAF "A7" E2AG |

"D" F2D2      D2EF | "A7" G2E2      E2A2 |\

"G" BABd "A7" cAce | "D"  d2d2      d2  :|

|:ag |\

"D" fdfa      fdfg | "A7" eceg eceg |\

"D" fdfa      fdfd | "A7" efgf e2ag |

"D" fdfa      fdfg | "A7" eceg ecAc |\

"G" BdcB "A7" AGFE | "D"  D2D2 D2  :|

%%vskip 20

 

X:15277

T:Reel des Oignons

S:Joseph Allard

S:Maine French Fiddlers, $2"In Memere's Kitchen".$0 Produced by Harry

S:King. Readfield, Maine, 1995.

M:2/4

L:1/16

R:Reel

G:Reels ~ Canadian ~ Quebec

H:This tune is from the NH Country Dance website. Look for more tunes

H:(New England, Canadian, Swedish) as well as resources for abc notation and

H:New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:G

"G" gage d2Bd | "D7" ((3cdc)A2 A4    | "D7" feee eddd | "G" dccc "D7" c2B2 |

"G" gage d2Bd    | "D7" ((3cdc)A2 A2>g2 | "D7" fgfe dcBA |1\

"G" G2"D7"B2 "G" [GB]2Bd       :|2     "G" G2"D7"B2 "G" G2 ||

|:Bc |\

"G" d2g2 g2fg    | "D7" a6Bc    | "D7" d2a2 a2ga | "G" b6Bc |

"G" d2g2 g2fg    | "D7" a6Bc    | "D7" d2a2 a2ba |1\

(& g6 & "G" x2"D7" x2"G" x2 &) :|2 (& g4 g4 & "G" x2"D7" x2"G" x4 &) |]

%%vskip 20

 

X:15364

T:Old French

M:2/4

L:1/16

R:Reel

G:Reels ~ Canadian ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:D

  ((3ABc) |\

"D" d2cd BdAF  | "D" DFAd f2ed | "A7" cdef gece | "D" defd A2 ((3ABc) |

"D" d2cd  BdAF | "D" DFAd f2ed | "A7" cdef gece | "D" d2f2 d2 :|

K:A

|:cd |\

"A" efed c2A2 | "A" AEAc e2dc | "G" B=GBd gfed | "A" cAce a2cd |

"A" efed c2A2 | "A" AEAc e2dc | "G" B=GBd gfed | "A" c2A2 A2  :|

 

X:15367

T:Old Grey Cat

N:A member of a band I used to play with once asked if I knew how to make the

N:cat meow. The answer is you play the two initial open E notes together with a D#.

M:C|

L:1/8

R:Reel

G:Reels ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:Em

  "Em" e2e2 E3F  | "Em" GFGA      BAB^c | "D"  d2d2 D3E   | "D"  FAdB AFED   |

  "Em" e2e2 E3F  | "Em" GFGA      BAB^c | "Bm" d^cBA BAGF | "Em" E4 e4      :|

|: "Em" B2e2 e3d  | "Em" Bdef      gfed  | "D"  A2d2d3B    | "D"  ABde fedf   |

  "Em" e2B2 g2B2 | "Am" a2B2 "Bm" b3a   | "Em" gfed "B7" BAB^d | "Em" e4 e4 :|

%%vskip 20

 

X:15364

T:Olde Tyme Quadrille

C:Bob McQuillen, June 1975

S:Chords are as played by Bob McQuillen on a recording of New England Tradition

S:from around 1985, to the best of my identification ability.

N:I listened to three recordings, and he played the chords differently on each one.

M: C

R:Reel

G:Reels ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K: D

FG|\

"D" ABde d2A2      | "D" B2A2 A2FG      | "D" ABde f2d2   | "A7" c6 EF         |

"A7" GAGF E2d2     | "A7" c2E2 E2EF     | "A7" GABd c2B2  | "D" B4 A2FG        |

"D" ABde d2A2      | "D" B2A2 A2FG      | "D" ABde f2d2   | "G" c2B2 "Em" B2cd |

"G" efed "Em" c2Bc | "D" defd "Bm" A2FA | "A7" B2d2  cdec | "D" d4-"F#7"d2     ||

dc|\

"Bm" BcBc d2f2        | "Bm" g2f2 fedc     | "Bm" Bcde f2d2       | "Bm" f6ef      |

"Em" gagf "Em/G" e2g2 | "D" fgfd "Bm" B2d2 | "F#7" c2B2 _B2=B2    | "F#7" c4 d3c   |

"Bm" BcBc d2f2        | "Bm" g2f2 fedc     | "Bm" Bcdc "D/A" B2f2 | "G" e6gf       |

"Em" e2B2 B2fe        | "Bm" d2B2 B2cd     | "F#7" c2g2 fedc      | "Bm" B4-"A7"B2 |]

%%vskip 20

 

X:15665

T:Over The Waterfall

M:4/4

L:1/4

R:Reel

G:Reels ~ LRB

H:From the Lamprey River Band Tunebook, a part of the NH Country Dance website.

H:Look for more tunes (New England, Canadian, Swedish) plus resources for

H:abc notation and New England traditional music and dance; URL below.

U:s = !slide!       % To preserve font, staff layout & other formatting,

U:t = !trill!       % use the file header at the URL below. There are

%%writefields NQSDZ % accompanying instructions for how to use it.

F:Tunes Home Page - http://fiddle.nhcountrydance.com/the-tunes.html

F:File Header & instructions - http://fiddle.nhcountrydance.com/headers.html

K:D

  d/2e/2|\

 "D" fa "A7" g/2f/2e | "D" dB Ad/2e/2 | "D" fa "A7" g/2f/2e | "D" d3 d/2e/2 |

 "D" fa "A7" g/2f/2e | "D" dB A>B     | "C" =cc     BA      | "G" G3       :|

|:F/2G/2|\

 "D" A2 "G"  B2 | "D" A/2B/2A/2G/2 FF/2G/2 | "D" Ad "A7" c/2d/2e | "D" d4  |

 "D" A2 "G"  B2 | "D" A/2B/2A/2G/2 FF/2G/2 | "D" AD "A7" G/2F/2E | "D" D3 :|

Header2TopLine
abc Codexx
Tune Links (16, indented)